Welcome to the Exelis VIS product documentation center! Here you will find reference guides, help documents, and product libraries. Discover the products ENVI, IDL, ENVI LiDAR, and ESE, developed by Exelis VIS.
﻿

### PLOT

PLOT

The PLOT function draws a line plot of vector arguments. If one parameter is used, the vector parameter is plotted on the ordinate versus the point number on the abscissa. To plot one vector as a function of another, use two parameters.

Instead of data, you can also input an equation of X using either the input argument or the EQUATION property. In this case IDL will automatically generate the independent X data and use your equation to compute the dependent Y data.

## Example

The following lines create the plot shown at the top of this topic.

`; Create data representing the sine wave`
`theory = SIN(2.0*FINDGEN(200)*!PI/25.0)*EXP(-0.02*FINDGEN(200))`
` `
`; Create the plot`
`plot = PLOT(theory, "r4D-", TITLE="Sine Wave")`
` `
`; Set some properties`
`plot.SYM_INCREMENT = 10`
`plot.SYM_COLOR = "blue"`
`plot.SYM_FILLED = 1`
`plot.SYM_FILL_COLOR = 0`

See Plot examples for additional examples using the PLOT function.

## Syntax

graphic = PLOT(Y, [Format] [, Keywords=value] [, Properties=value])

graphic = PLOT(X, Y, [Format] [, Keywords=value] [, Properties=value])

graphic = PLOT(Equation, [Format] [, Keywords=value] [, Properties=value])

### Keywords

Keywords are applied only during the initial creation of the graphic.

[, AXIS_STYLE={0|1|2|3}] [, /BUFFER] [, /CURRENT] [, /DEVICE] [, DIMENSIONS=array] [, LAYOUT=array] [, LOCATION=array] [, MARGIN=array] [, /NODATA] [, OVERPLOT=1 or variable] [, WINDOW_TITLE=string] [, Properties=variable]

### Properties

Properties can be set as keywords to the function during creation, or retrieved or changed using the "." notation after creation.

## Return Value

The PLOT function returns a reference to the created graphic. Use the returned reference to manipulate the graphic after creation by changing properties or calling methods.

## Arguments

### X

A vector representing the abscissa values to be plotted. If X is not specified, Y is plotted as a function of point number (starting at zero). If both arguments are provided, Y is plotted as a function of X.

### Y

The ordinate data to be plotted.

### Format

A string that sets line and symbol format properties using short tokens to represent color, symbol, linestyle, and thickness values. For example, to create a plot with a solid red line of thickness 2, using the '+' symbol to mark data points, you would use the following:

`p = PLOT(data, '-r2+')`

Tokens in the Format string represent values of the LINESTYLE, COLOR, THICK, and SYMBOL properties. From one to four tokens can be present, and the tokens may be in any order. Tokens are case sensitive. For more information about the syntax of the Format argument, see Formatting IDL Graphics Symbols and Lines.

### Equation

If the first argument is a string, then it is assumed to represent either an equation of X or the name of an IDL function that accepts an input argument X. Setting this argument is the same as setting the EQUATION property. See EQUATION for details.

## Keywords

### AXIS_STYLE

Set this keyword to one of the following values:

• 0 - No axes. Decrease the margins so the graphic almost fills the window. This is the default for images.
• 1 - Single X, Y (and Z if 3D) axes located at the minimum data value. The margins will be adjusted to leave space for the axes. This is the default for 3D graphics.
• 2 - Box axes - multiple axes located at both the minimum and maximum data values. The margins will be adjusted to leave space for the axes. This is the default for 2D graphics.
• 3 - Crosshair-style axes - located at the midpoint of each data dimension. Since the axes are in the middle, decrease the margins so the graphic almost fills the window. This is the default for polar plots.
• 4 - No axes, but use the same margins as if axes were there. This is useful if you want to later add another graphic that does have axes, and you want the two visualizations to be aligned properly.

You can set the following properties on the axes:

 Property Description [XYZ]COLOR A string or RGB vector containing the axis color. [XYZ]GRIDSTYLE A string, integer, or 2-element vector giving the linestyle for tickmarks. [XYZ]LOG Set to 1 if the axis is logarithmic. The minimum value of the axis range must be greater than zero. [XYZ]MAJOR The number of major tick marks. Set to -1 to auto-compute, set to 0 to suppress. [XYZ]MINOR The number of minor tick marks. Set to -1 to auto-compute, set to 0 to suppress. [XYZ]SUBGRIDSTYLE A string, integer, or 2-element vector giving the linestyle for the minor tickmarks. The default is 0, for solid lines. Set to -1 to force minor ticks to have the same linestyle as major ticks. [XYZ]SHOWTEXT Set to 1 to show text labels or 0 to hide the text labels. [XYZ]STYLE The axis range style. The valid values are: (0) Nice range. Default for all graphics except Image, Barplot, and Map. (1) Force the exact data range. Default for Image, Barplot, and Map. (2) Pad the axes slightly beyond the nice range. (3) Pad the axes slightly beyond the exact data range. Note: The [XYZ]RANGE takes precedence over this property. [XYZ]SUBTICKLEN The ratio of the minor tick length to the major tick length. The default is 0.5. [XYZ]TEXT_COLOR A string or RGB vector containing the axis text color. [XYZ]TEXT_ORIENTATION The angle (in degrees) of the tick mark labels. [XYZ]TEXTPOS Set to 1 to position text above the axis. The default is 0, below the axis. [XYZ]THICK Set to a floating-point value between 0 and 10 to specify the line thickness for tickmarks. A thickness of 0 gives a thin hairline. The default is 1. [XYZ]TICKDIR Set to 1 to draw the tickmarks facing outwards. The default is 0, facing inwards. [XYZ]TICKFONT_NAME A string containing the font name for the axis text. [XYZ]TICKFONT_SIZE The axis text size in points. [XYZ]TICKFONT_STYLE A string or integer containing the font style: normal (0), bold (1), italic (2), or bold italic (3). [XYZ]TICKFORMAT A string or string array of tick label formats. See Format Codes for more information. [XYZ]TICKINTERVAL The interval between major tick marks. [XYZ]TICKLAYOUT Set to 1 to suppress tick marks; set to 2 to draw a box around the tick labels. [XYZ]TICKLEN The length of each major tick mark, normalized to the width or height of the graphic. The default value is automatically calculated based upon the aspect ratio of the graphic. [XYZ]TICKNAME A string array containing the tick labels. [XYZ]TICKUNITS A string giving the tick units. Valid values are: null (the default, signified by empty quotes), Years, Months, Days, Hours, Minutes, Seconds, Time, exponent for exponential notation, or scientific for scientific notation. If any of the time units are utilized, then the tick values are interpreted as Julian date/time values. If more than one unit is provided, the axis will be drawn with multiple levels. [XYZ]TICKVALUES An array of tick mark locations. [XYZ]TITLE A string giving the axis title. [XYZ]TRANSPARENCY An integer from 0-100 giving the percent transparency.

For more detailed explanations of these properties, see the AXIS function.

Tip: You can also use the AXIS function to insert additional axes after the graphic has been created.

### BUFFER

Set this keyword to 1 to direct the graphics to an off-screen buffer instead of creating a window.

### CURRENT

Set this keyword to create the graphic in the current window. If no window exists, a new window is created. The WINDOW's SetCurrent method may be used to set the current window.

Or, set this keyword to an existing IDL Graphic reference to make that window be the current window and direct the new graphic to that window.

Note: If you need to place a second plot over the top of your first, set OVERPLOT=1 as well as using /CURRENT. Also see the examples in Two-Dimensional Plots for more information.

### DEVICE

Set this keyword if values are specified in device coordinates (pixels) for the MARGIN and POSITION keywords. (Normalized coordinates are the default for these keywords.)

### DIMENSIONS

Set this keyword to a two-element vector of the form [width, height] to specify the window dimensions in pixels. If you do not specify a value for DIMENSIONS, IDL by default uses the values of the IDL_GR_WIN_HEIGHT and IDL_GR_WIN_WIDTH preferences for Windows platforms or the IDL_GR_X_HEIGHT and IDL_GR_X_WIDTH preferences for X Windows systems on UNIX.

### LAYOUT

Set this keyword to a three-element vector [ncol, nrow, index] that arranges graphics in a grid. The first dimension ncol is the number of columns in the grid, nrow is the number of rows, and index is the grid position at which to place the graphic (starting at element 1). This keyword is ignored if either OVERPLOT or POSITION is specified.

### LOCATION

Set this keyword to a two-element vector [X offset, Y offset] giving the window's screen offset in pixels.

### MARGIN

Set this keyword to the current graphic’s margin values in the layout specified by the LAYOUT property. Use a scalar value to set the same margin on all sides, or use a four-element vector [left, bottom, right, top] to specify different margins on each side.

By default, margin values are expressed in normalized units ranging from 0.0 to 0.5. If the DEVICE keyword is set, the values are given in device units (pixels).

This keyword is ignored if either OVERPLOT or POSITION is specified.

### NODATA

Set this keyword to 1 to create the graphic, but without any data attached to it. The axes and title (if present) are also created and displayed. If the OVERPLOT keyword is specified, axis ranges will not change.

Note: You must still provide valid input arguments. The data range of the input arguments are used to automatically set the range of the axes. The [XYZ]RANGE properties may be used to override these default ranges.

### OVERPLOT

Set this keyword to 1 (one) to place the graphic on top of the existing graphic in the current window. If no current window exists, a new window is created.

Set this keyword to an existing IDL Graphic reference to direct the new graphic to the window specified by the provided IDL Graphic reference.

Note: If you need to place a second plot over the top of your first, set OVERPLOT=1 as well as using /CURRENT. Also see the examples in Two-Dimensional Plots for more information.

### WINDOW_TITLE

Set this keyword to the title of the IDL Graphic window. The title is displayed in the window's title bar.

## Properties

### ANTIALIAS

By default anti-aliasing is used when drawing lines. Set this property to 0 to disable anti-aliasing.

### ASPECT_RATIO

A floating point value indicating the ratio of the Y dimension to the X dimension in data units. If this property is set to a nonzero value, the aspect ratio will be preserved as the graphic is stretched or shrunk. The default value is 0 for all graphics except images, meaning that the aspect ratio is not fixed, but is allowed to change as the graphic is stretched or shrunk.

### AXES (Get Only)

This property retrieves an array that contains all of the AXIS objects within the visualization. For example, for a plot visualization:

`p = PLOT(/TEST)`
` ax = p.AXES`
`ax[0].TITLE = 'X axis'`
`ax[1].TITLE = 'Y axis'`
`ax[2].HIDE = 1  ; hide top X axis`
`ax[3].HIDE = 1  ; hide right Y axis`

See AXIS for a list of the available properties.

### BACKGROUND_COLOR

Set this property to a string or RGB vector indicating the graphic's background color. The default value is [255, 255, 255] (white). Set this property to a scalar value to remove the background color.

Tip: To set the background color of the entire window, retrieve the window object using the WINDOW property, and set the BACKGROUND_COLOR on the window object.

### BACKGROUND_TRANSPARENCY

Set this property to an integer between 0 and 100 giving the percent transparency of the background color. The default is 100 (completely transparent).

Note: If the BACKGROUND_COLOR property is changed, and the current background transparency is 100, then the BACKGROUND_TRANSPARENCY will be automatically set to 0 (opaque) so that you can see the new color.

### CLIP

Set this property to 1 to clip portions of the graphic that lie outside of the dataspace range, or to 0 to disable clipping. The default is 1.

### COLOR

Set this property to a string or RGB vector that specifies the color of the plot line.

Note: When you retrieve the COLOR property, the returned value will always be a three-element RGB vector, regardless of how the color was initially specified.

### CROSSHAIR (Get Only)

Use this property to retrieve a reference to the Crosshair graphic. All graphics objects within the same set of axes share a single Crosshair graphic. For Plot graphics the default behavior is to display the crosshair when a Mouse_Down event is received. For other graphics the crosshair is disabled. The STYLE property may be used to automatically draw the crosshair, while the LOCATION property may be used to manually draw the crosshair.

You can get and set the following properties on the retrieved crosshair:

 Property Description ANTIALIAS Set to 1 to enable anti-aliasing for the lines. COLOR A string or RGB vector containing the color. HIDE Set to 1 to hide the crosshair, 0 to show. INTERPOLATE Set to 1 to force interpolation between Plot data points when SNAP is active. For other graphics this property is ignored. The default is 0. LINESTYLE An integer or string giving the line style. The default is 'dot'. See "Linestyle Values" for additional options. LOCATION The location at which to draw the crosshair. For Plot graphics, if SNAP is enabled, then only the X coordinate needs to be supplied. Otherwise, LOCATION should be set to a two-element vector [X, Y] for two-dimensional graphics or [X, Y, Z] for three-dimensional graphics. If STYLE is currently "None", then setting the LOCATION will automatically set the STYLE to "Manual". NAME The name of the graphic. SNAP Set to 1 to snap the crosshair to the nearest Plot data point. For other graphics this property is ignored. The default is 1. STYLE An integer or string giving the crosshair style. Possible values are: 0 - "None" - never draw the crosshair. This is the default for all graphics except 2D plots. 1 - "Manual" - draw the crosshair using the LOCATION property. 2 - "Auto" - automatically draw the crosshair. This is the default for 2D plots. THICK The thickness of the lines. The default is 1. TRANSPARENCY The percent transparency of the lines. The default is 50. UVALUE An IDL variable of any data type.

For example, use the CROSSHAIR property to draw a crosshair on an image:

`im = IMAGE(/TEST, TRANSPARENCY=50, AXIS_STYLE=2)`
`c = im.CROSSHAIR`
`c.COLOR = 'red'`
`c.THICK = 2`
`c.LOCATION = [300, 200]`

See "Creating Functions to Control Mouse Events" for a more detailed crosshair example.

### EQN_SAMPLES

Set this property to an integer giving the number of samples to use with the EQUATION property. A higher value will give a smoother plot but will be slower to compute. The default is 1000 points. This property has no effect if EQUATION is not set.

### EQN_USERDATA

Set this property to an expression containing data of any type. If EQUATION is set to a function, and EQN_USERDATA is set, then the value of EQN_USERDATA will be passed in as the second argument to the function. If EQUATION is not set, or if EQUATION is set to an expression of X, then this property will have no effect.

### EQUATION

Set this property to a string that contains an equation. The equation can either be a valid IDL statement that has a variable named "x", or the name of a function that accepts a single argument, X. Note that your IDL statement (or function) must be able to handle an array of X values. In other words, all of the X values are passed in at once in a vector, not individually. The result of evaluating the equation with X should be another one-dimensional array containing the data to be plotted.

• When the plot is displayed, IDL will automatically construct a one-dimensional array X that spans the current axis range.
• The initial range is [-10, 10].
• If EQUATION is an expression, then IDL calls the EXECUTE function once with the X array. Note that in certain circumstances (such as the IDL Virtual Machine), you may not be able to use the EXECUTE function.
• If EQUATION is a function name, then IDL runs CALL_FUNCTION once, with the X array as the input argument. The function should return a one-dimensional result array.
• Once the equation is evaluated, IDL examines the result for any NaN values and the X range is clipped to only cover the valid region.
• The equation should be a "single" IDL statement (the "&" can not be used). If you need multiple statements, you should construct a function that accepts one argument, X, and put all of your code within the function.
• If you change the X axis range (either by using the mouse to pan around or using the XRANGE property), then a new set of X values is constructed and IDL calls your equation again with the new values.
• You can use EQN_SAMPLES to control the number of sampled points.
• You can use EQN_USERDATA to pass in user-defined data to your function.

#### Example of EQUATION Property with an Expression

The following code will produce a plot with a given equation:

`p = PLOT('SMOOTH(sin(1/x),9)', XRANGE=[0.01,0.2], \$`
`   /FILL_BACKGROUND, FILL_LEVEL=0)`

#### Example of EQUATION Property with a Function

To use the EQUATION property with a function, first create the function and save it into a file named ex_plotequation.pro somewhere on IDL's current path:

`FUNCTION ex_plotequation, x`
`  data = SMOOTH(sin(1/x),9)`
`  RETURN, data`
`END`

Then run the following code to use the equation:

`p = PLOT('ex_plotequation', XRANGE=[0.01,0.2], \$`
`   /FILL_BACKGROUND, FILL_LEVEL=0)`

For a more detailed example see Dynamic Visualizations.

### FILL_BACKGROUND

A value of 1 fills the area under the plot.

### FILL_COLOR

Set this property to a string or RGB vector that specifies the color of the filled area. The default value is [128,128,128] (gray). This property is ignored if FILL_BACKGROUND is not set.

### FILL_LEVEL

A floating point value specifying the Y value for a boundary of the fill region. This property is ignored if FILL_BACKGROUND is not set.

### FILL_TRANSPARENCY

An integer between 0 and 100 that specifies the percent transparency of the background fill. This property is ignored if FILL_BACKGROUND is not set.

### FONT_COLOR

Set this property to a string or RGB vector that specifies the text color of the title and axes (if present). The default value is "black".

### FONT_NAME

Set this property equal to a string specifying the IDL or system font for the title and axes (if present). The default value is “Helvetica”.

### FONT_SIZE

Set this property equal to an integer specifying the font size for the title and axes (if present). The default value is 12 points.

### FONT_STYLE

Set this property equal to an integer or a string specifying the font style for the title and axes (if present). Allowed values are:

 Integer String Resulting Style 0 "Normal" or "rm" Default (roman) 1 "Bold" or "bf" Bold 2 "Italic" or "it" Italic 3 "Bold italic" or "bi" Bold italic

### HIDE

Set this property to 1 to hide the graphic. Set HIDE to 0 to show the graphic.

### HISTOGRAM

Set this property to 1 to connect each point with horizontal and vertical lines. The horizontal lines start at the X location of each point and extend to the next X location. This property is useful for displaying information with discrete or non-linear data, where the X values are typically non-integer bin locations and the Y values represent the "count" of values within each bin. See the STAIRSTEP property for centered bars.

Tip: You can also use the BARPLOT function to create a plot with vertical or horizontal bars.

### LINESTYLE

Set this property to an integer or string giving the line style for the plot.

The following table lists the index values, strings, and characters you can use with the LINESTYLE property, and the equivalent characters and strings you can use in the Format string argument.

 Index LINESTYLE Property Format Argument Description 0 'solid_line', '-'(dash) '-' (dash) solid line 1 'dot', ':'(colon) ':'(colon) dotted 2 'dash', '--' (double dashes) '--' (double dashes) dashed 3 'dash_dot', '-.' '-.' dash dot 4 'dash_dot_dot_dot', '-:' '-:' dash dot dot dot 5 'long_dash', '__' (two underscores) '__' (double underscores) long dash 6 'none', ' ' (space) ' ' (space) no line

Note: If you use the LINESTYLE value or Format string '-.', the linestyle is set to dash-dot and the plot symbol is not set.

Note: You can also set LINESTYLE to a two-element vector, [repeat, bitmask], specifying a stippling pattern. The repeat indicates the number of times that individual bits in the bitmask should be repeated. (That is, if three consecutive 0’s appear in the bitmask and the value of repeat is 2, then the line that is drawn will have six consecutive bits turned off.) The value of repeat must be an integer between 1 and 255. The bitmask indicates which pixels are drawn and which are not along the length of the line. The bitmask should be specified as a 16-bit hexadecimal value. For example, LINESTYLE = [2, 'F0F0'X] describes a dashed line (8 bits on, 8 bits off, 8 bits on, 8 bits off).

### MAPGRID (Get Only)

If a map projection is currently in effect, this property retrieves a reference to the MAPGRID object.

### MAPPROJECTION (Get Only)

If a map projection is currently in effect, this property retrieves a reference to the MAPPROJECTION object.

### MAP_PROJECTION

A string giving the name of the current map projection. After creation, use this property to retrieve or set the current map projection.

### MAX_VALUE

The maximum value to be plotted. If this property is set, data values greater than the value of MAX_VALUE are treated as missing data and are not plotted.

Note: The IEEE floating point value NaN is also treated as missing data.

### MIN_VALUE

The minimum value to be plotted. If this property is set, data values less than the value of MIN_VALUE are treated as missing data and are not plotted.

Note: The IEEE floating point value NaN is also treated as missing data.

### NAME

A string that specifies the name of the graphic. The name can be used to retrieve the graphic using the brackets array notation. If NAME is not set then a default name is chosen based on the graphic type.

### POSITION

Set this property to a four-element vector that determines the position of the graphic within the window. The coordinates [X1, Y1, X2, Y2] define the lower left and upper right corners of the graphic. Coordinates are expressed in normalized units ranging from 0.0 to 1.0. On creation, if the DEVICE keyword is set, the units are given in device units (pixels).

Note: After creation, you can set the POSITION to either a two or four-element vector. If two elements are provided, the center of the graphic will be translated to that position. If four elements are provided, the graphics will be translated and scaled to fit the position.

### RGB_TABLE

The number of the predefined IDL color table, or a 3 x 256 or 256 x 3 byte array containing color values to use for vertex colors. If the values supplied are not of type byte, they are scaled to the byte range using BYTSCL. Use the VERT_COLORS property to specify indices that select colors from the values specified with RGB_TABLE.

### STAIRSTEP

Set this property to 1 to connect each point with horizontal and vertical lines. The horizontal lines are centered at each X location. This property is useful for displaying information with discrete or non-linear data, where the X values are typically integers and the Y values represent the "count" at that X location. See the HISTOGRAM property for bars that span X values.

Tip: You can also use the BARPLOT function to create a plot with vertical or horizontal bars.

### SYM_COLOR

Set this property to a string or RGB vector that specifies the color of the plot symbol. If this property is not set then the symbol color will match the COLOR.

### SYM_FILLED

Set this property to 1 to fill the symbols.

### SYM_FILL_COLOR

Set this property to a string or RGB vector that specifies the color of the filled portion of the symbol. If this property is not set then the symbol fill color will match the SYM_COLOR.

### SYM_INCREMENT

Set this property to an integer value specifying the number of plot vertices between symbols. The default value is 1, which places a symbol on every vertex.

### SYM_OBJECT

Set this property equal to an object reference to be used for the plotting symbol. The SYM_OBJECT may be either an IDLgrModel object or an atomic graphics object.

Note: When using custom plotting symbols, note that the SYM_OBJECT property takes precedence over the SYMBOL property. In other words, if you set a custom symbol using SYM_OBJECT, then try to change that symbol using the SYMBOL property, IDL ignores the new SYMBOL property and retains SYM_OBJECT.

### SYM_SIZE

A floating point value specifying the size of the plot symbol. A value of 1.0 produces a symbol that is 10% of the width/height of the plot.

### SYM_THICK

A floating point value from 1.0 to 10.0 that specifies the thickness (in points) of the plot symbol.

### SYM_TRANSPARENCY

An integer between 0 and 100 that specifies the percent transparency of the symbols. The default value is 0.

### SYMBOL

A string giving the symbol name. Allowed values are:

 "None" (the default) "Plus" or "+" "Asterisk" or "*" "Period" or "dot" "Diamond" or "D" "Triangle" or "tu" "Square" or "s" "X" "Greater_than" or ">" "Less_than" or "<" "Triangle_down" or "td" "Triangle_left" or "tl" "Triangle_right" or "tr" "Tri_up" or "Tu" "Tri_down" or "Td" "Tri_left" or "Tl" "Tri_right" or "Tr" "Thin_diamond" or "d" "Pentagon" or "p" "Hexagon_1" or "h" "Hexagon_2" or "H" "Vline" or "|" "Hline" or "_" "Star" or "S" "Circle" or "o"

Note that all plot symbol names are case sensitive.

Note: When using custom plotting symbols, note that the SYM_OBJECT property takes precedence over the SYMBOL property. In other words, if you set a custom symbol using SYM_OBJECT, then try to change that symbol using the SYMBOL property, IDL ignores the new SYMBOL property and retains SYM_OBJECT.

### THICK

Set this property to a value between 0 and 10 that specifies the plot line thickness. A thickness of 0 displays a thin hairline on the chosen device. The default value is 1.

### TITLE

Set this property to a string specifying a title. The title properties may be modified using FONT_COLOR, FONT_NAME, FONT_SIZE, and FONT_STYLE. After creation the TITLE property may be used to retrieve a reference to the title text object, and the TEXTproperties may be used to modify the title object.

You can also add Greek letters and mathematical symbols using a TeX-like syntax. These symbols need to be enclosed within a pair of "\$" characters. See Adding Mathematical Symbols and Greek Letters to the Text String for details on the available symbols.

### TRANSPARENCY

An integer between 0 and 100 that specifies the percent transparency of the plot line. The default value is 0.

### UVALUE

Set this property to an IDL variable of any data type.

### VERT_COLORS

A vector of indices into the color table for the color of each vertex (plot data point). Alternately, a 3 x N byte array containing vertex color values. If the values supplied are not of type byte, they are scaled to the byte range using BYTSCL. If indices are supplied but no colors are provided with the RGB_TABLE property, a default grayscale ramp is used. If a 3 x N array of colors is provided, the colors are used directly and the color values provided with RGB_TABLE are ignored. If the number of indices or colors specified is less than the number of vertices, the colors are repeated cyclically.

Note: VERT_COLORS can be an array of RGB triplets or RGBA colors.

### WINDOW (Get Only)

This property retrieves a reference to the WINDOW object which contains the graphic.

### XRANGE

A two-element vector giving the X data range to plot. The default behavior is to plot the entire data range.

### YRANGE

A two-element vector giving the Y data range to plot. The default behavior is to plot the entire data range.

### ZVALUE

A scalar value to be used as the z-coordinate for the entire plot. By default, 0.0 is used as the z-coordinate.

## Version History

 8.0 Introduced 8.1 Added the following properties: CROSSHAIR, MAPPROJECTION, MAP_PROJECTION, MAPGRID, UVALUE, WINDOW, [XYZ]SHOWTEXT, [XYZ]STYLE The THICK property was changed to accept a value between 0 and 10 Added the following methods: Delete, GetData, GetValueAtLocation, MapForward, MapInverse, SetData 8.2 Added AXES, BACKGROUND_COLOR, BACKGROUND_TRANSPARENCY, CLIP properties 8.2.1 [XYZ]TICKUNITS accepts exponent as a value, added ANTIALIAS property, added HISTOGRAM property. 8.2.2 Change POSITION from a keyword to a property. Changed HISTOGRAM property to start at each X value instead of centered on each X value. Added the STAIRSTEP property to center the bins at each X value. 8.2.3 Added the ability to use a stippling pattern for LINESTYLE. 8.3 Added Equation argument, and EQUATION, EQN_SAMPLES, and EQN_USERDATA properties.

﻿

## Notes

Eduardo Iturrate
Learn more about multiple plots in one window (a.k.a. multi-panel plots) in this blog post Making a multi-panel plot.
21st March 2013 9:16am
Fernando Santoro
The following two lines will plot a curve where the color of the line is proportional to a third parameter:

c=indgen(255)
p=plot(/test, VERT_COLORS=c, RGB_TABLE=13, THICK=5)

i.e, VERT_COLORS is the keyword to use.

Cheers,
Fernando
26th August 2013 10:08am
Page 1 of 1  (2 comments)

###### This information is not subject to the controls of the International Traffic in Arms Regulations (ITAR) or the Export Administration Regulations (EAR). However, it may be restricted from transfer to various embargoed countries under U.S. laws and regulations.
 PRODUCTS & SERVICES ENVI IDL Professional Services

 INDUSTRIES Defense & Intelligence Environmental Monitoring Academic
 LEARN Code Videos Events & Training Case Studies Whitepapers Resources
 SUPPORT Forums Help Articles Reference Guides Updates & Maintenance
 COMPANY Mission Careers Press Room Legal Exelis, Inc
© 2014 Exelis Visual Information Solutions